QQE signals
Pineスクリプトチュートリアルの解読を進める同時に、Trading Viewで公開されているインジケーターをいくつか拝見させてもらいました。その中で「QQE signals」これかなり使えるんじゃない？と感じました。以下、[1]インジケータ表示画像、[2]メリット・デメリット、[3]スクリプト、[4]スクリプト解釈を掲載します。もし[4]に間違いあったらゴメンナサイ(汗)
[1]画像(QQE signals)
[2-1]メリット(私の主観)
- Buy・Sellポイントが発生することで、エントリ方向を決めることができる
(ポジポジ病抑制、エントリ方向を明確にできる) - 他のオシレータ含め、複合的にエントリーや損切ポイントを考察できる
[2-2]デメリット(私の主観)
- エントリー頻度、エントリー精度はどの時間足を標準にするかで別物になる
(4時間足がエントリ頻度、エントリ精度のバランスが最も良さそうに思えた) - フラグ発生後エントリーになるため、実際のエントリールールは自身で決める必要がある
[3]スクリプト
//@version=4
// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © colinmck
study("QQE signals", overlay=true)
RSI_Period = input(14, title='RSI Length')
SF = input(5, title='RSI Smoothing')
QQE = input(4.238, title='Fast QQE Factor')
ThreshHold = input(10, title="Thresh-hold")
src = close
Wilders_Period = RSI_Period * 2 - 1
Rsi = rsi(src, RSI_Period)
RsiMa = ema(Rsi, SF)
AtrRsi = abs(RsiMa[1] - RsiMa)
MaAtrRsi = ema(AtrRsi, Wilders_Period)
dar = ema(MaAtrRsi, Wilders_Period) * QQE
longband = 0.0
shortband = 0.0
trend = 0
DeltaFastAtrRsi = dar
RSIndex = RsiMa
newshortband = RSIndex + DeltaFastAtrRsi
newlongband = RSIndex - DeltaFastAtrRsi
longband := RSIndex[1] > longband[1] and RSIndex > longband[1] ? max(longband[1], newlongband) : newlongband
shortband := RSIndex[1] < shortband[1] and RSIndex < shortband[1] ? min(shortband[1], newshortband) : newshortband
cross_1 = cross(longband[1], RSIndex)
trend := cross(RSIndex, shortband[1]) ? 1 : cross_1 ? -1 : nz(trend[1], 1)
FastAtrRsiTL = trend == 1 ? longband : shortband
// Find all the QQE Crosses
QQExlong = 0
QQExlong := nz(QQExlong[1])
QQExshort = 0
QQExshort := nz(QQExshort[1])
QQExlong := FastAtrRsiTL < RSIndex ? QQExlong + 1 : 0
QQExshort := FastAtrRsiTL > RSIndex ? QQExshort + 1 : 0
//Conditions
qqeLong = QQExlong == 1 ? FastAtrRsiTL[1] - 50 : na
qqeShort = QQExshort == 1 ? FastAtrRsiTL[1] - 50 : na
// Plotting
plotshape(qqeLong, title="QQE long", text="Long", textcolor=color.white, style=shape.labelup, location=location.belowbar, color=color.green, transp=0, size=size.tiny)
plotshape(qqeShort, title="QQE short", text="Short", textcolor=color.white, style=shape.labeldown, location=location.abovebar, color=color.red, transp=0, size=size.tiny)
// Alerts
alertcondition(qqeLong, title="Long", message="Long")
alertcondition(qqeShort, title="Short", message="Short")
- [4]スクリプト解釈 スクリプトの内容からRSIベースのインジケータで間違いないでしょう。QQE factor「4.238」の根拠はフィボナッチの233/55でしょうか？RSI振幅を長期、短期の追っかけによる売買フラグオシレータの観点では目新しくないですが、トレンドを変動させる足が発生するまで売買フラグ精度に工夫が費やされているのだと思います。
スイング向きのインジケータで真価を発揮するように思えます。売買後の次のフラグが立つ時にはポジションが腐る可能性がるので、ポジションクローズポイントは自身のルールで決めた方が良さそうです。
私のメインはセントラル短資です
